#
##################################################################
# cp.rul rule file for standard CounterPoint Accounting Software #
# Based upon CounterPoint 7.5.3 demo data                        #
# Requires UnForm version 5.0 or higher                          #
##################################################################
# This rule file is provided "AS IS", without warranty. #
# Under no circumstances will the publisher be liable   #
# for consequential damages resulting from the use or   #
# inability to use the contents.                        #
#########################################################
#
# NOTE: Any changes to forms or programs might force
#		changes to rule sets to be done

# Generic comments ######################################
#
# Make changes to all constants as needed.
#
# -------------------------------------------------------------
# To avoid problems associated with an upgrade overwriting
# this file in the future, you should copy this to a new
# name and reference that name in your printing configuration.
# -------------------------------------------------------------
# 
# This rule file includes rule sets for 
# 	O/E Picking Tickets, Invoices/Orders/Credit Memos
# 	P/O Purchase Orders
# 	A/R Statements

# Last modified 07/18/2002

# 07/11/2002 - bcj
#	Added rule set to handle purchase orders
# 07/16/2002 - bcj
#	Added rule set to handle statements
#	Added rule set to handle invoices, orders, credit memos
# 07/18/2002 - bcj
#	Added rule set to handle picking tickets

# Global constants #######################################

# Adjust the following constants to correct files and info
# if you use the subst file then replace each constant 
# with subst info in rule sets below
const COMP_NAME="Company Name: Edit rule file"
const COMP_ADDR1="Address 1"
const COMP_ADDR2="Address 2"
const COMP_ADDR3="Address 3"
const COMP_PHONES="###-###-####  Fax: ###-###-####"
const COMP_EMAIL="E-Mail: xxxx@xxxxxxxxxxxxxxx.com"
const COMP_WEBSITE="Website: www.xxxxxxxxxxxxxxx.com"

# Logos
const LOGO_IMAGE="image"		# remove # to turn on
const COMP_LOGO="sdsilogo.pcl"	# change to your logo file name

# watermarks
const WATERMARK_SHADE=10		# adjust to desired darkness
const WATERMARK="text"			# remove # to turn on

# PCL graphical shading uses a lot of memory
# suggest large start size
# change #gs on to  gs on to turn on  graphical shading
# change  gs on to #gs on to turn off graphical shading
const GSON="gs on"

# main heading constants
const HFONT=  univers,11
const HRFONT= univers,11,right
const HCFONT= univers,11,center
const HSHADE= 20
# bold
const HBFONT= univers,11,bold
const HBRFONT=univers,11,right,bold
const HBCFONT=univers,11,center,bold

# internal heading font constants (ribbons, detail headers)
const IFONT=  univers,9,italic
const ICFONT= univers,9,italic,center
const IPFONT= univers,9,italic,decimal
const IRFONT= univers,9,italic,right
const ISHADE= 15
# bold
const IBFONT= univers,9,italic,bold
const IBCFONT=univers,9,italic,center,bold
const IBPFONT=univers,9,italic,decimal,bold
const IBRFONT=univers,9,italic,right,bold

# detail data font constants
const DFONT=  cgtimes,10
const DCFONT= cgtimes,10,center
const DPFONT= cgtimes,10,decimal
const DRFONT= cgtimes,10,right
const DSHADE= 10
# bold
const DBFONT= cgtimes,10,bold
const DBCFONT=cgtimes,10,center,bold
const DBPFONT=cgtimes,10,decimal,bold
const DBRFONT=cgtimes,10,right,bold

# detail data font constants for wide forms
const DSFONT=  cgtimes,9
const DSCFONT= cgtimes,9,center
const DSPFONT= cgtimes,9,decimal
const DSRFONT= cgtimes,9,right
# bold
const DSBFONT= cgtimes,9,bold
const DSBCFONT=cgtimes,9,center,bold
const DSBPFONT=cgtimes,9,decimal,bold
const DSBRFONT=cgtimes,9,right,bold

# default major section box size
const MBOXSIZE=5

#***************************************************************
#                     Merge rule sets                          *
#***************************************************************

[Mrg Form Header]
LOGO_IMAGE 1,1,12,6,"COMP_LOGO"
text 1,2,{doc_title$},HBRFONT,16,cols=MAXRCOLS
text 1,2,{compname$},HBCFONT,14,cols=MAXRCOLS
text 1,3.2,{addr1$},HCFONT,12,cols=MAXRCOLS
text 1,4.3,{addr2$},HCFONT,12,cols=MAXRCOLS
text 1,5.4,{addr3$},HCFONT,12,cols=MAXRCOLS
text 1,6.5,{phone$},HCFONT,12,cols=MAXRCOLS
text 1,7.5,"COMP_EMAIL",HCFONT,cols=MAXRCOLS
text 1,8.5,"COMP_WEBSITE",HCFONT,cols=MAXRCOLS

[Mrg get company info]
# get comp info from page or constants?
compname$=trim(get(xcol,xrow,xcols+20))
if compname$="" then \
		compname$="COMP_NAME"; \
		addr1$="COMP_ADDR1"; \
		addr2$="COMP_ADDR2"; \
		addr3$="COMP_ADDR3"; \
		phone$="Phone: COMP_PHONES" \
	else \
		addr1$=trim(get(xcol,xrow+1,xcols)); \
		addr2$=trim(get(xcol,xrow+2,xcols)); \
		addr3$=trim(get(xcol,xrow+3,xcols)); \
		phone$=trim(get(xcol,xrow+4,xcols)); \
		if phone$="" then if addr3$="" or \
				addr3$(1,1)>="A" then \
				phone$="Phone: COMP_PHONES" \
			else \
				phone$=addr3$,addr3$="" \
			else 	phone$=phone$
if addr3$="" then addr3$=phone$,phone$=""

[Mrg get watermark text]
wmlines=1
wdoc_title$=doc_title$
x=pos(" "=wdoc_title$)
if x>0 then wdoc_title$=trim(doc_title$(1,x)) + $0a$ + \
	trim(doc_title$(x+1)); wmlines=wmlines+1

#***************************************************************
#                 Most frequently used rule sets               *
#***************************************************************

[O/E Picking Ticket]
# used PIKPP form ID
detect 0,4,"P I C K I N G   T I C K E T"

# set up document constants
const MAXCOLS=81					# max cols to output
const MAXRCOLS=80					# MAXCOLS-1
const LEFTCOL=.5					# left vertical line
const RIGHTCOL=81.5				# right vertical line
const MAXROWS=66					# max rows to output

portrait
dpi 600

cols MAXCOLS					# max output columns
rows MAXROWS					# max output rows
page MAXROWS					# max input rows

const WAREHOUSE_COPY=1
const MAX_COPIES=1
pcopies MAX_COPIES

# see global constant above
GSON							# graphical shading

title "Picking Ticket"				# view in pdf properties

prejob {
	dim copy_title$[MAX_COPIES]
	if MAX_COPIES>=1 then \
		copy_title$[WAREHOUSE_COPY]="Warehouse Copy"
}

prepage {
	doc_title$=trim(get(25,4,30))
	# save word split
	x=pos("   "=doc_title$)
	if x then doc_title$=doc_title$(1,x-1)+$10$+doc_title$(x+3)
remove_spaces:
	x=pos(" "=doc_title$)
	if x then doc_title$=doc_title$(1,x-1)+doc_title$(x+1); \
		goto remove_spaces
	# restore word split
	x=pos($10$=doc_title$)
	if x then doc_title$=doc_title$(1,x-1)+" "+doc_title$(x+1)
	merge "Mrg get watermark text"

	compname$=trim(get(10,1,50))
}

# erase lines
hline "--",erase

# default line enhancement
const BROW=26
const EROW=55
cfont 1,BROW,6,EROW,DBCFONT				# loc/seq
cfont 8,BROW,34,EROW,DFONT				# item #/desc
cfont 36,BROW,45,EROW,DBRFONT				# qty ord
cfont 47,BROW,54,EROW,DCFONT				# unit
cfont 56,BROW,67,EROW,DBRFONT				# qty to ship
cfont 69,BROW,MAXRCOLS,EROW,DBRFONT			# qty shipped

# header section
vshift 3							# make room for logo
cerase 1,1,MAXCOLS,6
cbox LEFTCOL,1,RIGHTCOL,MAXROWS,MBOXSIZE,crows=11:MBOXSIZE
LOGO_IMAGE 1,1,12,6,"COMP_LOGO"
text 1,2,{doc_title$},HBRFONT,16,cols=MAXRCOLS
text 1,2,{compname$},HBCFONT,14,cols=MAXRCOLS

# handle copy title
cbox 60,2.75,RIGHTCOL,4.25,1,100
text 61,3.6,{copy_title$[copy]},HBCFONT,12,cols=20,shade 0

# order ribbon
cbox LEFTCOL,9,RIGHTCOL,11,1, \
	ccols=9::ISHADE 27 35::ISHADE 54 61::ISHADE 72 77::ISHADE  
cfont 1,10,8,10,IRFONT					# ord #
cfont 10,10,22,10,DBFONT				# ord #
cfont 24,10,34,10,IRFONT				# ord date
cfont 36,10,50,10,DBFONT				# ord date
cfont 52,10,60,10,IRFONT				# loc
cfont 62,10,70,10,DBFONT				# loc
cfont 72,10,76,10,IRFONT				# page
cfont 78,10,MAXRCOLS,10,DBFONT			# page

# sold to section
cbox LEFTCOL,11,RIGHTCOL,17,MBOXSIZE,ccols=5::ISHADE 44 49::ISHADE
cfont 1,12,4,13,IRFONT					# sold to
cfont 6,12,40,16,DBFONT					# customer

# ship to section
cfont 45,12,48,13,IRFONT				# ship to
cfont 50,12,MAXCOLS,16,DBFONT				# customer

# cust ribbon
cbox LEFTCOL,17,RIGHTCOL,21,MBOXSIZE
cbox LEFTCOL,17,RIGHTCOL,19,1, \
	ccols=8::ISHADE 24 30::ISHADE 49 55::ISHADE 73 77::ISHADE  
cfont 1,18,7,18,IRFONT					# cust #
cfont 9,18,22,18,DBFONT					# cust #
cfont 24,18,29,18,IRFONT				# po
cfont 31,18,47,18,DBFONT				# po
cfont 49,18,54,18,IRFONT				# terms
cfont 56,18,71,18,DBFONT				# terms
cfont 73,18,76,18,IRFONT				# slp
cfont 78,18,MAXRCOLS,18,DBFONT			# slp

# ship via ribbon
cbox LEFTCOL,19,RIGHTCOL,21,1, \
	ccols=10::ISHADE 32 42::ISHADE 57 68::ISHADE
cfont 1,20,9,20,IRFONT					# ship via
cfont 11,20,27,20,DBFONT				# ship via
cfont 29,20,41,20,IRFONT				# date to ship
cfont 43,20,53,20,DBFONT				# date to ship
cfont 55,20,67,20,IRFONT				# date shipped
cfont 69,20,MAXRCOLS,20,DBFONT			# date shipped

# detail
cbox LEFTCOL,22,RIGHTCOL,56,MBOXSIZE,crows=25::DSHADE, \
	ccols=7 35 46 55 68
const BROW=23
const EROW=24
cfont 1,BROW,6,EROW,ICFONT				# loc/seq
cfont 8,BROW,34,EROW,IFONT				# item #/desc
cfont 36,BROW,45,EROW,IRFONT				# qty ord
cfont 47,BROW,54,EROW,ICFONT				# unit
cfont 56,BROW,67,EROW,IRFONT				# qty to ship
cfont 69,BROW,MAXRCOLS,EROW,IRFONT			# qty shipped

# handle serial #'s
font "Serial-#'s",-10,3,37,1,DFONT

# handle B/O balance
font "Ref:",0,3,37,1,DFONT

# watermark - large font with light shading
WATERMARK 1,{54-9*(wmlines-1)},{wdoc_title$},cgtimes,120, \
	shade=WATERMARK_SHADE,center,cols=MAXCOLS, \
	fit,spacing=1

# footer
# comments
cbox LEFTCOL,56,RIGHTCOL,MAXROWS,MBOXSIZE,crows=62
cfont 1,57,9,57,IFONT						# title
cfont 11,57,MAXCOLS,57,DFONT					# comments
cfont 1,58,MAXCOLS,61,DFONT					# comments

# totals
cfont 1,63,20,63,DFONT						# # of items
cfont 38,63,52,64,IFONT						# title
cfont 54,63,67,64,DBRFONT					# pcs/wt

[O/E Invoice/Order]
# used INVP1 form ID
detect 0,5,"Invoice"

# set up document constants
const MAXCOLS=81					# max cols to output
const MAXRCOLS=80					# MAXCOLS-1
const LEFTCOL=.5					# left vertical line
const RIGHTCOL=81.5				# right vertical line
const MAXROWS=66					# max rows to output

portrait
dpi 600

cols MAXCOLS					# max output columns
rows MAXROWS					# max output rows
page MAXROWS					# max input rows

const CUSTOMER_COPY=1
const ACCOUNTING_COPY=2
const PACKING_COPY=3
const MAX_COPIES=3
pcopies MAX_COPIES

# see global constant above
GSON							# graphical shading

title "Invoice"					# view in pdf properties

prejob {
	dim copy_title$[MAX_COPIES]
	if MAX_COPIES>=1 then \
		copy_title$[CUSTOMER_COPY]="Customer Copy"
	if MAX_COPIES>=2 then \
		copy_title$[ACCOUNTING_COPY]="Accounting Copy"
	if MAX_COPIES>=3 then \
		copy_title$[PACKING_COPY]="Customer Copy"
}

prepage {
	doc_title$="INVOICE"
	if trim(get(69,5,10))="" then \
		doc_title$="ORDER"
	if cnum(get(71,58,10))<0 or cnum(get(71,62,10))<0 then \
		doc_title$="CREDIT MEMO"
	xdoc_title$=doc_title$
	xcol=6,xrow=5,xcols=30
	merge "Mrg get company info"
}

precopy {
	doc_title$=xdoc_title$
	if copy=PACKING_COPY then \
		doc_title$="PACKING SLIP"
	merge "Mrg get watermark text"

	valid_pack$="INVOICE, ORDER, PACKING SLIP"
	if pos(xdoc_title$=valid_pack$)=0 \
		and copy=PACKING_COPY then skip=1
}

# erase lines
hline "--",erase

# default line enhancement
const BROW=26
const EROW=56
cfont 1,BROW,8,EROW,DBRFONT				# qty
cfont 10,BROW,13,EROW,DCFONT				# unit
cfont 15,BROW,29,EROW,DBFONT				# item #
cfont 31,BROW,55,EROW,DFONT				# desc
cfont 57,BROW,64,EROW,DBRFONT				# price
cfont 66,BROW,69,EROW,DCFONT				# unit
cfont 71,BROW,MAXRCOLS,EROW,DBRFONT			# extension

# header section
cerase 1,1,MAXCOLS,12
cbox LEFTCOL,1,RIGHTCOL,MAXROWS,MBOXSIZE,crows=12:MBOXSIZE
merge "Mrg Form Header"					# merge std hdr rules

# handle copy title
cbox 62,2.75,RIGHTCOL,4.25,1,100
text 63,3.6,{copy_title$[copy]},HBCFONT,12,cols=18,shade 0

# right header
cbox 62,5.5,RIGHTCOL,10.5,1,ccols=70::ISHADE,crows=6.5 7.5 8.5 9.5
text 63,6,{cut(58,5,11,"")},IRFONT,cols=7
text 63,7,{cut(58,6,11,"")},IRFONT,cols=7
text 63,8,{cut(58,7,11,"")},IRFONT,cols=7
text 63,9,{cut(58,9,11,"")},IRFONT,cols=7
text 63,10,{cut(58,10,11,"")},IRFONT,cols=7
text 71,6,{cut(70,5,8,"")},DBFONT,cols=8
text 71,7,{cut(70,6,8,"")},DBFONT,cols=8
text 71,8,{cut(70,7,8,"")},DBFONT,cols=8
text 71,9,{cut(70,9,8,"")},DBFONT,cols=8
text 71,10,{cut(70,10,8,"")},DBFONT,cols=8

# sold to section
cbox LEFTCOL,12,RIGHTCOL,20,MBOXSIZE,ccols=5::ISHADE 44 49::ISHADE
cfont 1,13,4,14,IRFONT					# sold to
cfont 6,13,40,19,DBFONT					# customer

# ship to section
cfont 42,13,48,14,IRFONT				# ship to
cfont 50,13,MAXCOLS,19,DBFONT				# customer

# ribbon section
cbox LEFTCOL,20,RIGHTCOL,23,MBOXSIZE,crows=21.5, \
	ccols=7::ISHADE 20 27::ISHADE 40 46::ISHADE 65 72::ISHADE
text 1,21,{cut(1,21,4,"")},IRFONT,cols=6			# cust
text 8,21,{cut(6,21,12,"")},DBFONT				# cust

text 1,22,{cut(1,22,8,"")},IRFONT,cols=6			# salesman
text 8,22,{cut(10,22,7,"")},DBFONT				# salesman

text 18,21,{cut(19,21,9,"")},IRFONT,cols=9		# ship date
text 28,21,{cut(29,21,8,"")},DBFONT				# ship date

cfont 18,22,26,22,IRFONT					# po #
text 28,22,{cut(25,22,11,"")},DBFONT			# po #

cfont 38,21,45,22,IRFONT					# ship via/terms
cfont 47,21,62,22,DBFONT					# ship via/terms

cfont 64,21,71,22,IRFONT					# ord #/date
text 73,21,{cut(75,21,6,"")},DBFONT				# ord #
cfont 73,22,MAXRCOLS,22,DBFONT				# ord date

# detail
cbox LEFTCOL,23,RIGHTCOL,57,MBOXSIZE, \
	crows=25::DSHADE,ccols=9 14 30
if copy 1,2
	cbox 56,23,RIGHTCOL,57,1,ccols=65 71
end if
# detail headings
cfont 1,24,8,24,IRFONT					# qty
cfont 10,24,13,24,ICFONT				# unit
cfont 15,24,29,24,ICFONT				# item #
cfont 31,24,55,24,ICFONT				# desc
cfont 57,24,64,24,IRFONT				# price
cfont 66,24,69,24,ICFONT				# unit
cfont 71,24,MAXRCOLS,24,IRFONT			# extension

if copy 3
	cerase 57,24,MAXRCOLS,57
end if

# handle serial #'s
font "Serial #'s",0,0,MAXCOLS,1,DFONT

# handle B/O balance
font "B/O Balance",0,0,11,1,DFONT

# watermark - large font with light shading
WATERMARK 1,{55-9*(wmlines-1)},{wdoc_title$},cgtimes,120, \
	shade=WATERMARK_SHADE,center,cols=MAXCOLS, \
	fit,spacing=1

# footer
cbox LEFTCOL,57,RIGHTCOL,MAXROWS,MBOXSIZE
if copy 1,2
	cbox 56,57,RIGHTCOL,MAXROWS,1,ccols=65::HSHADE
end if
cfont 1,56,54,64,DFONT					# remarks
cfont 56,58,64,65,IRFONT				# total titles
cfont 66,58,MAXRCOLS,65,DBRFONT,11			# totals
if copy 3
	erase 56,58,MAXRCOLS,65
end if

[A/R Statements]
# used STMPP form ID
detect 0,6,"S T A T E M E N T"

# set up document constants
const MAXCOLS=81					# max cols to output
const MAXRCOLS=80					# MAXCOLS-1
const LEFTCOL=.5					# left vertical line
const RIGHTCOL=81.5				# right vertical line
const MAXROWS=66					# max rows to output

portrait
dpi 600

cols MAXCOLS					# max output columns
rows MAXROWS					# max output rows
page MAXROWS					# max input rows

const CUSTOMER_COPY=1
const REMITTANCE_COPY=2
const ACCOUNTING_COPY=3
const MAX_COPIES=3
pcopies MAX_COPIES

# see global constant above
GSON							# graphical shading

title "Statement"					# view in pdf properties

prejob {
	dim copy_title$[MAX_COPIES]
	if MAX_COPIES>=1 then \
		copy_title$[CUSTOMER_COPY]="Customer Copy"
	if MAX_COPIES>=2 then \
		copy_title$[REMITTANCE_COPY]="Remittance Copy"
	if MAX_COPIES>=3 then \
		copy_title$[ACCOUNTING_COPY]="Accounting Copy"
}

prepage {
	doc_title$=trim(get(52,6,17))
remove_spaces:
	x=pos(" "=doc_title$)
	if x then doc_title$=doc_title$(1,x-1)+doc_title$(x+1); \
		goto remove_spaces
	merge "Mrg get watermark text"

	xcol=6,xrow=3,xcols=30
	merge "Mrg get company info"
}

# erase lines
hline "--",erase

# default line enhancement
const BROW=24
const EROW=52
cfont 1,BROW,8,EROW,DBCFONT				# date
cfont 10,BROW,12,EROW,DBCFONT				# type
cfont 14,BROW,23,EROW,DBCFONT				# doc #
cfont 25,BROW,39,EROW,DBCFONT				# po #
cfont 41,BROW,65,EROW,DSFONT				# desc
cfont 67,BROW,{MAXRCOLS-1},EROW,DBRFONT		# amount
cfont MAXRCOLS,BROW,MAXRCOLS,EROW,DBFONT,black	# neg (-)

# header section
cerase 1,1,MAXCOLS,13
cbox LEFTCOL,1,RIGHTCOL,MAXROWS,MBOXSIZE,crows=13:MBOXSIZE
merge "Mrg Form Header"					# merge std hdr rules

# handle copy title
cbox 64,2.75,RIGHTCOL,4.25,1,100
text 65,3.6,{copy_title$[copy]},HBCFONT,12,cols=16,shade 0

# to section
cbox LEFTCOL,13,RIGHTCOL,21,MBOXSIZE,ccols=47 62::ISHADE
cfont 6,15,40,18,DBFONT					# customer
cfont 46,14,61,18,IRFONT
cfont 63,14,MAXRCOLS,18,DBFONT

# detail
cbox LEFTCOL,21,RIGHTCOL,52,MBOXSIZE, \
	crows=23::DSHADE,ccols=9 13 24 40 66
# detail headings
cfont 1,22,8,22,ICFONT					# date
cfont 10,22,12,22,ICFONT				# type
cfont 14,22,23,22,ICFONT				# doc #
cfont 25,22,39,22,ICFONT				# po #
cfont 41,22,65,22,IFONT					# desc
cfont 67,22,{MAXRCOLS-1},22,IRFONT			# amount

# handle child customers
font "Totals for child",0,0,40,1,DFONT

# watermark - large font with light shading
WATERMARK 1,50,{wdoc_title$},cgtimes,120, \
	shade=WATERMARK_SHADE,center,cols=MAXCOLS, \
	fit,spacing=1

# footer
cbox LEFTCOL,52,RIGHTCOL,MAXROWS,MBOXSIZE,crows=55 58
cfont 1,53,MAXCOLS,54,DBCFONT

cfont 1,56,25,57,DBFONT
cfont 34,56,48,57,DBCFONT
cfont 52,56,{MAXRCOLS-1},56,DBRFONT
cfont MAXRCOLS,56,MAXRCOLS,56,DBRFONT,black,10

cfont 1,59,17,60,DRFONT
cfont 18,59,33,60,DRFONT,black
cfont 34,59,49,60,DRFONT
cfont 50,59,65,60,DRFONT,black
cfont 66,59,MAXRCOLS,60,DRFONT

[P/O Purchase Orders]
# used PLN60 plain paper Form ID
detect 0,3,"PURCHASE ORDER"

# set up document constants
const MAXCOLS=81					# max cols to output
const MAXRCOLS=80					# MAXCOLS-1
const LEFTCOL=.5					# left vertical line
const RIGHTCOL=81.5				# right vertical line
const MAXROWS=66					# max rows to output

portrait
dpi 600

cols MAXCOLS					# max output columns
rows MAXROWS					# max output rows
page MAXROWS					# max input rows

const VENDOR_COPY=1
const ACCOUNTING_COPY=2
const MAX_COPIES=2
pcopies MAX_COPIES

# see global constant above
GSON							# graphical shading

title "Purchase Order"				# view in pdf properties

prejob {
	dim copy_title$[MAX_COPIES]
	if MAX_COPIES>=1 then \
		copy_title$[VENDOR_COPY]="Vendor Copy"
	if MAX_COPIES>=2 then \
		copy_title$[ACCOUNTING_COPY]="Accounting Copy"
}

prepage {
	doc_title$=trim(get(66,3,14))
	merge "Mrg get watermark text"

	xcol=5,xrow=3,xcols=30
	merge "Mrg get company info"
}

# erase lines
hline "--",erase

# default line enhancement
const BROW=25
const EROW=66
cfont 1,BROW,3,EROW,DBCFONT				# line #
cfont 5,BROW,19,EROW,DBFONT				# item #
cfont 21,BROW,45,EROW,DSBFONT				# desc
cfont 47,BROW,59,EROW,DBRFONT				# Qty/Price
cfont 62,BROW,65,EROW,DSBCFONT			# unit
cfont 67,BROW,MAXRCOLS,EROW,DBRFONT			# extension

# header section
cerase 1,1,MAXCOLS,9
cbox LEFTCOL,1,RIGHTCOL,MAXROWS,MBOXSIZE,crows=9.5:MBOXSIZE
merge "Mrg Form Header"					# merge std hdr rules

# handle copy title
cbox 62,2.75,RIGHTCOL,4.25,1,100
text 63,3.6,{copy_title$[copy]},HBCFONT,12,cols=18,shade 0

# right header
cbox 62,4.5,RIGHTCOL,9.5,1,ccols=70::ISHADE,crows=5.5 6.5 7.5 8.5
text 63,5,{cut(54,4,11,"")},IRFONT,cols=7,fit
text 63,6,{cut(54,5,11,"")},IRFONT,cols=7,fit
text 63,7,{cut(54,6,11,"")},IRFONT,cols=7,fit
text 63,8,{cut(54,7,11,"")},IRFONT,cols=7,fit
text 63,9,{cut(54,8,11,"")},IRFONT,cols=7,fit
text 71,5,{cut(66,4,15,"")},DBFONT,cols=9,fit
text 71,6,{cut(66,5,15,"")},DBFONT,cols=9,fit
text 71,7,{cut(66,6,15,"")},DBFONT,cols=9,fit
text 71,8,{cut(66,7,15,"")},DBFONT,cols=9,fit
text 71,9,{cut(66,8,15,"")},DBFONT,cols=9,fit

# to section
cbox LEFTCOL,9.5,RIGHTCOL,14,MBOXSIZE,ccols=10::ISHADE 44 50::ISHADE
cfont 6,10,7,10,IRFONT
cfont 11,10,40,13,DBFONT

# ship to section
cfont 45,10,48,11,IRFONT
cfont 51,10,MAXCOLS,13,DBFONT

# vendor #/contact section
cbox LEFTCOL,14,RIGHTCOL,18,ccols=10::ISHADE
cfont 1,15,9,16,IRFONT
cfont 11,15,MAXCOLS,16,DBFONT

# ribbon section
cbox LEFTCOL,18,RIGHTCOL,21,MBOXSIZE,crows=19.5::ISHADE, \
	ccols=17 34 65
cfont 1,19,16,19,ICFONT				# fob
cfont 18,19,33,19,ICFONT			# ship via
cfont 35,19,64,19,ICFONT			# terms
cfont 66,19,RIGHTCOL,19,ICFONT		# buyer

text 1,20,{cut(1,20,15,"")},DBCFONT,fit,cols=15		# fob
text 18,20,{cut(18,20,16,"")},DBCFONT,fit,cols=16	# ship via
text 35,20,{cut(35,20,30,"")},DBCFONT,fit,cols=30	# terms
text 66,20,{cut(66,20,15,"")},DBCFONT,fit,cols=15	# buyer

# detail
cbox LEFTCOL,21,RIGHTCOL,58,MBOXSIZE, \
	crows=24::DSHADE,ccols=4 20 46 61 67
# detail headings
cfont 1,22,3,23,ICFONT					# line #
cfont 5,22,19,23,IFONT					# item #
cfont 21,22,45,23,IFONT					# desc
cfont 47,22,59,23,IRFONT				# qty/price
cfont 62,22,65,23,ICFONT				# unit
cfont 67,22,MAXRCOLS,23,IRFONT			# extension

# watermark - large font with light shading
WATERMARK 1,47,{wdoc_title$},cgtimes,120, \
	shade=WATERMARK_SHADE,center,cols=MAXCOLS, \
	fit,spacing=1

# footer
cbox LEFTCOL,58,RIGHTCOL,60,MBOXSIZE,crows=60, \
	ccols=12::HSHADE 27 36::HSHADE 54 65::HSHADE
cfont 1,59,11,59,HRFONT					# # of lines
cfont 13,59,24,59,DBFONT,10
cfont 26,59,35,59,HRFONT				# total qty
cfont 37,59,51,59,DBFONT,10
cfont 53,59,64,59,HRFONT				# total price
cfont 66,59,MAXRCOLS,59,DBRFONT,10

# notes
cbox LEFTCOL,60,RIGHTCOL,MAXROWS,MBOXSIZE
cfont 1,61,7,61,IRFONT
cfont 9,61,MAXCOLS,65,DFONT

#***************************************************************
#              Less frequently used rule sets                  *
#***************************************************************


#***************************************************************
#              Inactive or testing rule sets                   *
#***************************************************************


#***************************************************************
#              Old Modification History                        *
#***************************************************************